! D1. ACE Model for Power Calculations
! Power calculation with classical twin design
! Part 1: simulate the data

! To simulate: 
!    30% additive genetic   (.5477^2=.3)
!    20% common environment (.4472^2=.2)
!    50% random environment (.7071^2=.5)

G1: genetic structure
Data Calc NGroups=5
Matrices
A Lower 1 1 Fixed
Compute A*A' /
Matrix A .5477 
End

G2: common environmental structure
Data Calc 
Matrices
C Lower 1 1 Fixed
Compute C*C' /
Matrix C .4472 
End

G3: specific environmental structure
Data Calc 
Matrices
E Lower 1 1 Fixed
Compute E*E' /
Matrix E .7071
End

G4: MZ twin pairs
Data Calc NInput_vars=2 
Matrices
A Symm 1 1 = %E1  ! expected matrix of group 1
C Symm 1 1 = %E2  ! expected matrix of group 2
E Symm 1 1 = %E3  ! ..
Covariances A+C+E | A+C _
            A+C   | A+C+E /
Options MX%E=mzsim.cov  
Options NO_output
End

G5: DZ twin pairs
Data Calc NInput_vars=2 
Matrices
A Symm 1 1 = %E1
C Symm 1 1 = %E2
E Symm 1 1 = %E3
H Full 1 1
Covariances A+C+E  | H@A+C _
            H@A+C  | A+C+E /
Matrix H .5
Options MX%E=dzsim.cov
Options NO_output  
End

! The simulation is complete.  Now the next, stacked, problem
! will fit the wrong model to the simulated data

G1: genetic structure
Data Calc NGroups=5
Matrices
A Lower 1 1 Free
Compute A*A' /
End

G2: common environmental structure
Data Calc 
Matrices
C Lower 1 1 Fixed
Compute C*C' /
End

G3: specific environmental structure
Data Calc 
Matrices
E Lower 1 1 Free
Compute E*E' /
End

G4: MZ twin pairs
Data NInput_vars=2 NObservations=1000
Labels Twin_1 Twin_2
CMatrix Full File=mzsim.cov
Matrices
A Symm 1 1 = %E1  ! expected matrix of group 1
C Symm 1 1 = %E2  ! expected matrix of group 2
E Symm 1 1 = %E3  ! ..
Covariances A+C+E | A+C _
            A+C   | A+C+E /
Options RSiduals
End

G5: DZ twin pairs
Data NInput_vars=2 NObservations=1000
Labels Twin_1 Twin_2
CMatrix Full File=dzsim.cov
Matrices
A Symm 1 1 = %E1
C Symm 1 1 = %E2
E Symm 1 1 = %E3
H Full 1 1
Covariances A+C+E  | H@A+C _
            H@A+C  | A+C+E /
Matrix H .5
Start .5 All
Options RSiduals Power= .05,1     ! For .05 level of sig. and 1 df.
End