! Bivariate Genetic Cholesky Model
! Alcohol Consumption and Sensitivity in Australian male twins

G1: model parameters
Data Calc NGroups=3
Begin Matrices;
X Lower 2 2 Free    ! genetic structure
Y Lower 2 2         ! common environmental structure
Z Lower 2 2 Free    ! specific environmental structure
W Lower 2 2         ! dominance structure
End Matrices;
Specify Y 0 0 7
Specify W 8 9 0
Begin Algebra;
A= X*X' ;
C= Y*Y' ;
E= Z*Z' ;
D= W*W' ;
End Algebra;
End

G2: female MZ twin pairs
Data NInput_vars=4 NObservations=43
Labels cons_t1 sens_t1 cons_t2 sens_t2
CMatrix Symmetric File=ozalcmzf.cov
Select sens_t1 cons_t1 sens_t2 cons_t2 
Matrices= Group 1
Covariances A+C+E+D | A+C+D _
            A+C+D   | A+C+E+D /
Option RSidual
End 

G3: young female DZ twin pairs
Data NInput_vars=4 NObservations=42
Labels cons_t1 sens_t1 cons_t2 sens_t2
CMatrix Symmetric File=ozalcdzf.cov
Select sens_t1 cons_t1 sens_t2 cons_t2 
Matrices= Group 1
H Full 1 1
Q Full 1 1
Covariances A+C+E+D   | H@A+C+Q@D _
            H@A+C+Q@D | A+C+E+D /
Matrix H .5
Matrix Q .25
Start .6 All
Option RSidual
Options NDecimals=4
End