! Rater Bias Model
! CBC data in US twins

G1: model parameters
Data Calc NGroups=7
Begin Matrices;
X Lower 1 1 Free    ! genetic factor on latent phenotype
Y Lower 1 1 Free    ! common env factor on latent phenotype
Z Lower 1 1 Free    ! specific env factor on latent phenotype
B Full 4 2          ! rater bias factors 
F Diag 4 4          ! specific environmental specifics
S Diag 2 2          ! factor structure
I Iden 2 2
End Matrices;
Specify B
4 0
4 0
0 5
0 5 
Specify F 
6 6 7 7
Specify S 15 15
Begin Algebra;
A= X*X' ;
C= Y*Y' ;
E= Z*Z' ;
R= B*B';
J= F*F' ;
End Algebra;
End

G2: model parameters
Data Calc
Begin Matrices;
X Lower 1 1 Free    ! genetic factor on latent phenotype
Y Lower 1 1 Free    ! common env factor on latent phenotype
Z Lower 1 1 Free    ! specific env factor on latent phenotype
B Full 4 2          ! rater bias factors 
F Diag 4 4          ! specific environmental specifics
S Diag 2 2          ! factor structure
I Iden 2 2
End Matrices;
Specify B
11 0
11 0
0 12
0 12 
Specify F
13 13 14 14 
Specify S 19 19
Begin Algebra;
A= X*X' ;
C= Y*Y' ;
E= Z*Z' ;
R= B*B';
J= F*F' ;
End Algebra;
End

G3: MZ boys twin pairs
Data NInput_vars=4 NObservations=96
Labels morg_t1 morg_t2 farg_t1 farg_t2
CMatrix File=uscbcmzm.cov
Matrices= Group 1
Covariances R+ J+ ((I_S)*(A+C+E | A+C _
                          A+C   | A+C+E )*(I_S)') /
Option RSidual
End 

G4: DZ boys twin pairs
Data NInput_vars=4 NObservations=102
Labels morg_t1 morg_t2 farg_t1 farg_t2
CMatrix File=uscbcdzm.cov
Matrices= Group 1
H Full 1 1
Covariances R+ J+ ((I_S)*(A+C+E | H@A+C _
                          H@A+C | A+C+E )*(I_S)') /
Matrix H .5
Option RSidual
End

G5: MZ girls twin pairs
Data NInput_vars=4 NObservations=102
Labels morg_t1 morg_t2 farg_t1 farg_t2
CMatrix File=uscbcmzf.cov
Matrices= Group 2
Covariances R+ J+ ((I_S)*(A+C+E | A+C _
                          A+C   | A+C+E )*(I_S)') /
Option RSidual
End 

G6: DZ girls twin pairs
Data NInput_vars=4 NObservations=97
Labels morg_t1 morg_t2 farg_t1 farg_t2
CMatrix File=uscbcdzf.cov
Matrices= Group 2
H Full 1 1 = H4
Covariances R+ J+ ((I_S)*(A+C+E | H@A+C _
                          H@A+C | A+C+E )*(I_S)') /
Option RSidual
End

G7: DZ girl-boy twin pairs
Data NInput_vars=4 NObservations=103
Labels morg_t1 morg_t2 farg_t1 farg_t2
CMatrix File=uscbcdzo.cov
Matrices= Group 1
M Symm 1 1 = A2
N Symm 1 1 = C2
O Symm 1 1 = E2
S Diag 2 2 
R Full 4 2
J Diag 4 4
H Full 1 1 = H4
Covariances 
R*R'+ J*J'+ ((I_S)* (M+N+O | H@(\sqrt(A*M))+\sqrt(C*N) _       
                     H@(\sqrt(A*M))+\sqrt(C*N) | A+C+E)* (I_S)') /
Specify S
19 15
Specify R
11 0
4 0
0 12
0 5 
Specify J
13 6 14 7
Start .2 All
Start .5 X 1 1 1 Y 1 1 1 Z 1 1 1 X 2 1 1 Y 2 1 1 Z 2 1 1
Option RSidual
Options NDecimals=4 Iterations=200
End