G1: Model parameters
 Data Calc NGroups=4
 Begin Matrices;
 ! parameters are fixed by default, unless declared free
  H Full 1 1
  O Zero 1 2
  Q Full 1 1
  U Unit 1 1
  X Lower 1 1 Free
  Y Lower 1 1 Free
  Z Lower 1 1 Free
  W Lower 1 1 
 End Matrices;
 ! elements are zero by default, unless declared otherwise
 Matrix H .5
 Matrix Q .25
 Start .6 All
 Begin Algebra;
  A= X*X'; 
  C= Y*Y';
  E= Z*Z';
  D= W*W';
  M= A+C+D+E | A+C+D _
     A+C+D   | A+C+D+E ;      ! MZ covariance
  N= A+C+D+E   | H@A+C+Q@D _
     H@A+C+Q@D | A+C+D+E ;    ! DZ covariance
 End Algebra:
End

G2: young female MZ twin pairs
 Data Ninput=3 
 Ordinal File=mzpr.frq
 Labels T1 T2 Freq
 Definition Freq ;
 Begin Matrices= Group 1
  T full 1 2
  F full 1 1 ! Frequency
 End Matrices;
 Matrix T .4814 .4814  ! Fixed (!)
 Specify F Freq
 Covariances M ;
 Thresholds T ;
 Frequency F;
 Weight U%(U-\mnor(M_O_T_T_O));
 Options RSidual
End 

G3: young female DZ twin pairs
 Data Ninput=3
 Labels T1 T2 Freq
 Ordinal File=dzpr.frq
 Definition Freq ;

 Begin Matrices= Group 1
  T Full 1 2 = T2
  F full 1 1 ! Frequency
 End Matrices;
 Specify F Freq

 Covariances N;
 Thresholds T ;
 Frequency F ;
 Weight U%(U-\mnor(N_O_T_T_O));
 Options RSidual NDecimals=4
End

Group 4: constrain variance to 1
 Constraint NI=1
 Begin Matrices = Group 1 ;
  I unit 1 1
 End Matrices;

 Constraint I = A+C+E+D ;
 Option Multiple
End